Quick swap of mods and saves

[HeilTec]

I like to avoid copying files when not needed, and the mklink /j command allows just that.
To make it a little easier I use different versions of this:

bat

Code: Select all

@ECHO Remove mods and saves Directories ( or junctions if that is what it is )
@ECHO Hit Ctrl-C to cancel ...
pause
rmdir mods
rmdir saves
mklink /j mods  ..\FactorioH-modpacks\Amass-bob\mods
mklink /j saves ..\FactorioH-modpacks\Amass-bob\saves
@ECHO Done ...
pause

Note: rmdir will not remove a normal folders with files - only empty folders and links.

Install:
1. Make a backup of saves and mods folders.
2. Create a folder to hold the modpacks (see folders I use)
3. Copy the selected mods ands saves to the respective folders in the mod-packs.
4. Place the .bat-files in the game folder.
5. delete saves and mods folders and files in game folder (you have the backup - right?)

Use:
1. To change mods Factorio must be terminated (exit)
2. Double-click the apropriate mod-pack .bat (2x enter to confirm and close)
3. start Factorio.

.bat-files are for windows
linux users will just make their own scripts
Mac users - I don't know.

folders

Code: Select all

Folders I use:

<parent>\FactorioH (home game folder)	(add the .bat-files here)
        |
        \FactorioH-ModPacks
         -
           \Amass-bob
            -
             \saves
             \mods
           \rso-farl-pack
            -
             \saves
             \mods

[HeilTec]

I am lazy. I act proactively on that. So I spent a little more time on making it even easier.

amass-bob.bat

Code: Select all

@echo off

:check_run
tasklist /FI "IMAGENAME eq factorio.exe" 2>NUL | find /I /N "factorio.exe">NUL
if "%ERRORLEVEL%"=="0" goto ask2quit
goto do_links

:ask2quit
echo Factorio detected. Please exit factorio and ...
pause
goto check_run

:do_links
@ECHO Removing mods and saves Directories ( or junctions if that is what it is )
@ECHO Hit Ctrl-C to cancel or ...
pause
rmdir mods
rmdir saves
mklink /j mods  ..\FactorioH-modpacks\Amass-bob\mods
mklink /j saves ..\FactorioH-modpacks\Amass-bob\saves
@ECHO Done ...
pause
bin\x64\Factorio.exe

[Artorp]

Hey, I didn't want separate .bat files for each modpack so I repurposed this to allow you to pick which modpack you want to use. Also allows me to easily add more modpacks, and use one shortcut to launch the game.

I haven't bothered switching the save folder yet so I didn't include that, I guess I should but eh, make sure you make adjustments if needed.

My folder structure is a bit different:

folders

Code: Select all

Folders I use:

<parent>\Factorio (game appdata folder)	(add the .bat-files here)
        |
        \fmm
         -
           \modpack1
           \modpack2

factorio_mod_pick_from_list.bat

Code: Select all

@echo off

SETLOCAL EnableDelayedExpansion

:check_run
tasklist /FI "IMAGENAME eq factorio.exe" 2>NUL | find /I /N "factorio.exe">NUL
if "%ERRORLEVEL%"=="0" goto ask2quit
goto initial_dir_scan

:ask2quit
echo Factorio detected. Please exit factorio and ...
pause
goto check_run

:initial_dir_scan
SET count=1
FOR /D %%I IN (fmm\*) DO (
    @ECHO !count! : %%I
    set /a count+=1
)
goto ask_dir

:ask_dir
set /P user_choice=Enter desired mod directory (as a number):
SET count=1
SET chosen_dir=""
FOR /D %%I IN (fmm\*) DO (
    if "!user_choice!" == "!count!" (
        set chosen_dir=%%I
    )
    set /a count+=1
)
if EXIST "%chosen_dir%" goto links_setup
@ECHO Incorrect input & goto ask_dir

:links_setup
@ECHO Removing previous mod directory ( or junction )
rmdir /q mods
mklink /j mods "%chosen_dir%"
@ECHO Done!
@ECHO Want me to start Factorio? Ctrl-C if no, or...
pause
C:\SteamApps\Factorio\bin\x64\Factorio.exe

Picture

cmd_2016-04-27_04-49-39.png (28.68 KiB) Viewed 9333 times

[steinio]

Nice.

I wish this is provided by the game itself in 0.13.

[Artorp]

Here's an implementation that includes save folders, the folder structure is a bit different.

Note: Steam users need to disable cloud saving, otherwise Steam will try to download the missing saves each time the game launches.

My folder structure with mods and saves in modpacks:

folders

Code: Select all

Folder structure:

<parent>\Factorio     (game appdata folder)	(put the .bat-file here)
        |
        \mods
        \saves
        \fmp
         -
           \modpack1
            -
              \mods
              \saves
           \modpack2
            -
              \mods
              \saves

factorio_mod_pick_from_list.bat

Code: Select all

@echo off

SETLOCAL EnableDelayedExpansion

:check_run
tasklist /FI "IMAGENAME eq factorio.exe" 2>NUL | find /I /N "factorio.exe">NUL
if "%ERRORLEVEL%"=="0" goto ask2quit
goto initial_dir_scan

:ask2quit
echo Factorio detected. Please exit factorio and ...
pause
goto check_run

:initial_dir_scan
SET count=1
FOR /D %%I IN (fmp\*) DO (
    @ECHO !count! : %%I
    set /a count+=1
)
goto ask_dir

:ask_dir
set /P user_choice=Enter desired modpack (as a number):
SET count=1
SET chosen_dir=""
FOR /D %%I IN (fmp\*) DO (
    if "!user_choice!" == "!count!" (
        set chosen_dir=%%I
    )
    set /a count+=1
)
if EXIST "%chosen_dir%\mods" (
    if EXIST "%chosen_dir%\saves" (
        goto links_setup
    ) ELSE (
        @ECHO %chosen_dir%\saves - folder not found
    )
) ELSE (
    @ECHO %chosen_dir%\mods - folder not found
)
@ECHO Incorrect input or folder structure & goto ask_dir

:links_setup
@ECHO Removing previous mods and saves directories ( or junctions )
rmdir /q mods
rmdir /q saves
mklink /j mods "%chosen_dir%\mods"
mklink /j saves "%chosen_dir%\saves"
@ECHO Done!
@ECHO Want me to start Factorio? Ctrl-C if no, or...
pause
C:\SteamApps\Factorio\bin\x64\Factorio.exe